Резервное копирование настроек EVE

После очередной переустановки операционной системы, либо после очередного глюка приходится заново настраивать весь клиент EVE Online. Чтобы этого избежать можно время от времени сохранять папку с настройками.

Путь к настройкам в Windows XP:
%USERPROFILE%\Local Settings\Application Data\CCP\EVE

Путь к настройкам в Windows 7:
%USERPROFILE%\AppData\Local\CCP\EVE

Чтобы всегда иметь под рукой актуальную копию настроек можно использовать специальные программы, например, EveHQ. Есть и другой способ (я использую именно его) - написать простенький командный файл и добавит его в планировщик заданий. Этот метод более гибкий, т.к. мы полностью управляем всем процессом архивирования, можем подстроить его под себя.

Вот текст BAT-файла:

Код:: @echo off

rem ********************************************************************
rem Командный файл для резервного копирования настроек EVE Online
rem
rem Переменные:
rem SOURCE - путь к настройкам игры:
rem    для WinXP %USERPROFILE%\Local Settings\Application Data\CCP\EVE
rem    для Win7 %USERPROFILE%\AppData\Local\CCP\EVE
rem BACKUP - путь к папке для резервного копирования
rem ZIP - путь к архиватору 7-Zip
rem
rem ********************************************************************

set SOURCE="%USERPROFILE%\AppData\Local\CCP\EVE"
set ZIP="%PROGRAMFILES%\7-Zip"
set BACKUP="D:\BackUp\EveBackup\Backup"

rem ********************************************************************

cd /d "%ZIP%"

rem Создаем новый каталог для сохранения файлов
set BACKUP=%BACKUP%\%DATE%
if exist %BACKUP% (
rem Удаляем старый каталог
   rd /s /q %BACKUP%
)
md %BACKUP%

rem Выполняем обход всех каталогов
for /d %%i in (%SOURCE%\*) do (
rem Проверяем наличие папки с настройками
if exist %%i\settings (
   rem Копируем настройки
   xcopy "%%i\settings" "%BACKUP%\%%~ni\settings\" /s
   rem Помещаем настройки в архив
   7z a "%BACKUP%\settings.zip" "%BACKUP%\%%~ni\"
   rem Удаляем скопированные данные
   rd /s /q "%BACKUP%\%%~ni"
)
)

rem Делаем паузу, если небыл передан параметр hide
if not "%1"=="hide" (
PAUSE
)

Чтобы создать командный файл, копируем код, вставляем его в Блокнот и сохраняем, указав расширение ".bat". При запуске этого файла настройки всех клиентов будут помещены в zip-архив в указанную вами папку. Сейчас все настроено для работы с архиватором 7-Zip, но при желании можно настроить и на любой другой. Отредактировать командный файл можно в том же Блокноте.

После проверки работоспособности создаем задание в Планировщике заданий и выставляем время запуска нашего файла (например, во время даун тайма). Чтобы окошко автоматически закрывалось указываем параметр "hide".

Вот пример запуска из командной строки:
C:\EveBackup.bat hide

Готовый файл можно скачать тут: EveBackup.zip